|
采集 标签:模块示例|采集 模块说明
人物靠近可采集资源时，屏幕中间会出现采集按钮
点击采集按钮，进度条走完可获得采集奖励，采集资源消失（怪物被杀死）
采集过程中，人物移动或被攻击将中断采集 相关配置
可采集资源通过在地图刷新怪物实现
..\Mir200\Envir\MonGen.txt- 第18个参数
- 2-可采集怪(带墓碑效果，采集完有墓碑)
- 3-可采集怪(无墓碑效果，采集完没有墓碑)
采集奖励通过配置怪物掉落，配合采集时杀死怪物的命令nearKillMon实现
..\Mir200\Envir\MonItems\
特戒引擎脚本示例：
;..\scripts\Mir200\Envir\QuestDiary\采集\采集.txt
[@main]
#if
;检测人物附近有没有可采集物
checkRangeMonCountEX 神龙山庄 高级神物 <$X> <$Y> 3 > 0
#act
mov S$采集怪物名字 高级神物
goto @采集按钮显示
break
#if
;检测人物附近有没有可采集物
checkRangeMonCountEX 神龙山庄 低级神物 <$X> <$Y> 3 > 0
#act
mov S$采集怪物名字 低级神物
goto @采集按钮显示
break
#elseact
goto @采集按钮隐藏
[@采集按钮显示]
#if
check [3007] 0
#act
set [3007] 1
goto @采集中
[@采集按钮隐藏]
#if
check [3007] 1
#act
set [3007] 0
delMainCenterBtn 采集中按钮
[@采集中]
#if
;检测人物体力值是否满足采集消耗
large U80 14
#act
addMainCenterBtn 采集中按钮 2 lc_wajue,lc_caiji_jishi2,5000,采集中 0,-100 可采集 250 32 0,-183 lc_wajue_di <$X>,<$Y>,7,1 采集中,采集进度条走完
#elseact
addMainCenterBtn 采集中按钮 1 lc_wajue 0,-100 可采集 250 32 0,-183 lc_wajue_di 0,0,0,1 体力不足
[@体力不足]
#if
#act
sendTipsMSG 体力不足：15
[@采集进度条走完]
#if
#act
delMainCenterBtn 采集中按钮
;杀死采集资源怪并获取掉落
nearKillMon 3 <$str(S$采集怪物名字)> 1
dec U80 15
sendTipsMSG 采集成功
#call [\采集\采集.txt] @神龙山庄侧边栏
#elseact
sendTipsMSG 采集失败
;QFunction-0.txt的触发器会调用这里
[@采集失败]
#if
check [3007] 1
#act
set [3007] 0
delMainCenterBtn 采集中按钮
;位于采集地图时任务侧边栏的显示
[@神龙山庄侧边栏]
#if
#act
mov U3036 1
#if
#act
mov N3015 0
getRangeMonCount 神龙山庄 90 88 500 N3007 神魔矿工首领
getRangeMonCount 神龙山庄 90 88 500 N3008 神魔骑兵首领
getRangeMonCount 神龙山庄 90 88 500 N3009 神魔刀兵首领
getRangeMonCount 神龙山庄 90 88 500 N3010 神魔力士首领
inc N3015 N3007
inc N3015 N3008
inc N3015 N3009
inc N3015 N3010
getRangeMonCount 神龙山庄 90 88 500 N3011 低级神物
getRangeMonCount 神龙山庄 90 88 500 N3012 高级神物
mov N3016 0
getRangeMonCount 神龙山庄 90 88 500 N3013 魔神半兽人
getRangeMonCount 神龙山庄 90 88 500 N3014 魔神兽人
inc N3016 N3013
inc N3016 N3014
#if
isOnMap 神龙山庄
#act
mov s$sideInfo3
inc s$sideInfo3 <text:当前体力剩余：<$str(U80)>{fcolor=250}:10:0>
inc s$sideInfo3 <text:山庄魔神消耗：30{fcolor=161}:10:40>
inc s$sideInfo3 <text:山庄首领消耗：5{fcolor=161}:10:80>
inc s$sideInfo3 <text:山庄圣物消耗：15{scolor=161}:10:120>
inc s$sideInfo3 <text:魔神剩余数量：<$str(N3016)>{scolor=251}:10:160>
inc s$sideInfo3 <text:首领剩余数量：<$str(N3015)>{scolor=251}:10:200>
inc s$sideInfo3 <text:高级神物数量：<$str(N3012)>{scolor=251}:10:240>
inc s$sideInfo3 <text:低级神物数量：<$str(N3011)>{scolor=161}:10:280>
mov s$sideInfo4
inc s$sideInfo4 <text:当前体力剩余：<$str(U80)>{fcolor=250}:0:0:150:10:16>
inc s$sideInfo4 <text:山庄魔神消耗：30{fcolor=161}:0:30:150:10:16>
inc s$sideInfo4 <text:山庄首领消耗：5{fcolor=161}:0:60:150:10:16>
inc s$sideInfo4 <text:山庄圣物消耗：15{scolor=161}:0:90:150:10:16>
inc s$sideInfo4 <text:魔神剩余数量：<$str(N3016)>{scolor=251}:0:120:150:10:16>
inc s$sideInfo4 <text:首领剩余数量：<$str(N3015)>{scolor=251}:0:150:150:10:16>
inc s$sideInfo4 <text:高级神物数量：<$str(N3012)>{scolor=251}:0:180:150:10:16>
inc s$sideInfo4 <text:低级神物数量：<$str(N3011)>{scolor=161}:0:210:150:10:16>
mov s$setPic main_task_geren_02,main_task_geren_01,main_task_hanghui_02,main_task_hanghui_01
#if
isOnMap 神龙山庄
#act
;手机端处理
addDlg 1 dlg:<$str(s$sideInfo3)>dlg: 1 <$str(s$setPic)> 0
;pc端处理
addDlg 1 dlg:<$str(s$sideInfo4)>dlg: 2 <$str(s$setPic)> 0
;..\Mir200\Envir\Market_Def\QFunction-0.txt
;被法术攻击时触发
[@MagicStruck]
;打断采集进度条，采集失败
#if
isOnMap 神龙山庄
#act
#call [\采集\采集.txt] @采集失败
;被攻击时触发
[@Struck]
;打断采集进度条，采集失败
#if
isOnMap 神龙山庄
#act
#call [\采集\采集.txt] @采集失败
;跑触发
[@run]
;打断采集进度条，采集失败
#if
isOnMap 神龙山庄
#act
#call [\采集\采集.txt] @采集失败
;走触发
[@walk]
;打断采集进度条，采集失败
#if
isOnMap 神龙山庄
#act
#call [\采集\采集.txt] @采集失败
=====================================================
现有的自动采集只能采集尸体，不能采集其他
命令只能采集尸体！
使用模块-采集 制作的均无法实现自动采集，(点击自动战斗，使用的是新模式挂机，会一直跑，不自动采集，使用以下命令也无法解决)
[@StartAutoPlayGame]
#act
;开启人物挂机时自动采集尸体
autoCorpseCollection 1
建议，增加一个自动采集非尸体的功能，超级紧急，等着用！
| 
发表于 
发表于 